renameFields Function

Option Explicit
Sub Main
	If Not renameFields(sFile, OldFieldName, NewFieldName) Then
		MsgBox "The field could not be renamed"
	End If
	
End Sub


'*****************************************************************************************************************************************
'* Function: renameFields
'* Purpose: To rename fields within a file
'* Input:	sTempFilename: the name of the imd file that contains the fields to change
'* 	sOldFieldName: The name of the field that is to be changed
'*	sNewFieldName: The new field name
'* Returns: True if fieldname was changed False if the field name could not be changed
'* Problems: Currently does not work for some Editable fields
'*****************************************************************************************************************************************
Function renameFields(sTempFilename As String, sOldFieldName As String, sNewFieldName As String) As Boolean
	On Error GoTo ErrorHandler
	Dim db As database
	Dim table As table
	Dim task As task
	Dim field As field
	Dim newField As Object
	Dim iFieldType As Integer
	Dim sDescription As String
	Dim iDecimals As Integer
	Dim bImpliedDecimals As Boolean
	Dim iLen As Integer
	Dim sEqn As String
	
	Set db = client.openDatabase(sTempFilename)
	Set table = db.tabledef
	Set field = table.getfield(sOldFieldName)
	iFieldType = field.Type
	
	'obtain the old info
	sDescription = field.Description

	Select Case iFieldType
		Case WI_NUM_FIELD, WI_VIRT_NUM, WI_BOOL, WI_MULTISTATE  
			iDecimals = field.Decimals
			bImpliedDecimals = field.IsImpliedDecimal
			sEqn = field.Equation
		Case WI_CHAR_FIELD
			iLen = field.Length
		Case WI_VIRT_CHAR
			iLen = field.Length
			sEqn = field.Equation
		Case WI_DATE_FIELD, WI_TIME_FIELD, WI_VIRT_DATE, WI_VIRT_TIME
			sEqn = field.Equation
			
	End Select
	
	Set db = Nothing
	Set table = Nothing 
	Set field = Nothing

	'change the field name
	Set db = client.openDatabase(sTempFilename)
	Set task = db.TableManagement
	Set table = db.tabledef
	Set newField = table.NewField
	
	newField.Name = sNewFieldName
	newField.Description = sDescription

	Select Case iFieldType
		Case WI_NUM_FIELD, WI_VIRT_NUM
			If iFieldType = WI_NUM_FIELD Then
				newField.Type = WI_NUM_FIELD
			Else
				newField.Type = WI_VIRT_NUM
			End If
			newField.Decimals = iDecimals
			newField.IsImpliedDecimal = bImpliedDecimals
			newField.Equation = sEqn
		Case WI_CHAR_FIELD
			newField.Type = WI_CHAR_FIELD
			newField.Length = iLen
		Case WI_VIRT_CHAR
			newField.Type = WI_VIRT_CHAR
			newField.Length = iLen
			newField.Equation = sEqn
		Case WI_DATE_FIELD
			newField.Type = WI_DATE_FIELD
			newField.Equation = sEqn
		Case WI_VIRT_DATE
			newField.Type = WI_VIRT_DATE
			newField.Equation = sEqn
		Case WI_TIME_FIELD
			newField.Type = WI_TIME_FIELD
			newField.Equation = sEqn
		Case WI_VIRT_TIME
			newField.Type = WI_VIRT_TIME
			newField.Equation = sEqn
		Case WI_BOOL  
			newField.Type = WI_BOOL  
			newField.Decimals = iDecimals
			newField.IsImpliedDecimal = bImpliedDecimals
			newField.Equation = sEqn
		Case WI_MULTISTATE 
			newField.Type = WI_MULTISTATE 
			newField.Decimals = iDecimals
			newField.IsImpliedDecimal = bImpliedDecimals
			newField.Equation = sEqn

	End Select
	
	task.ReplaceField sOldFieldName, newField
	task.PerformTask
	
	renameFields = true
	
	GoTo ReleaseVariables
	
ErrorHandler:	
	renameFields = false
ReleaseVariables:
	Set task = Nothing
	Set db = Nothing
	Set table = Nothing
	Set field = Nothing
	Set newField = Nothing
	
	
End Function